     [file docstyle.texi not included]

D-Bus integration in Emacs
**************************

This manual documents an API for usage of D-Bus in Emacs.  D-Bus is a message bus system, a simple way for applications to talk to one another.  An overview of D-Bus can be found at https://dbus.freedesktop.org/.

Copyright © 2007--2025 Free Software Foundation, Inc.

     Permission is granted to copy, distribute and/or modify this document under the terms of the GNU Free Documentation License, Version 1.3 or any later version published by the Free Software Foundation; with no Invariant Sections, with the Front-Cover Texts being ``A GNU Manual'', and with the Back-Cover Texts as in (a) below.  A copy of the license is included in the section entitled ``GNU Free Documentation License''.

     (a) The FSF's Back-Cover Text is: ``You have the freedom to copy and modify this GNU manual.''

An overview of D-Bus
********************

D-Bus is an inter-process communication mechanism for applications residing on the same host.  Emacs uses it when it is compiled with the respective library, see configuration option --with-dbus.  At runtime, the form (featurep 'dbusbind) indicates D-Bus support.

D-Bus communication is based on messages.  Data in the messages is carried in a structured way, it is not just a byte stream.

The communication is connection oriented to two kinds of message buses: a so called system bus, and a session bus.  On a given machine, there is always one single system bus for miscellaneous system-wide communication, like changing of hardware configuration. On the other hand, the session bus is always related to a single user's session.

Every client application, which is connected to a bus, registers under a unique name at the bus.  This name is used for identifying the client application.  Such a unique name starts always with a colon, and looks like :1.42.

Additionally, a client application can register itself to a so called known name, which is a series of identifiers separated by dots, as in org.gnu.Emacs.  If several applications register to the same known name, these registrations are queued, and only the first application which has registered for the known name is reachable via this name.  If this application disconnects from the bus, the next queued unique name becomes the owner of this known name.

An application can install one or several objects under its name. Such objects are identified by an object path, which looks similar to paths in a filesystem.  An example of such an object path could be /org/gnu/Emacs/.

Applications might send a request to an object, that means sending a message with some data as input parameters, and receiving a message from that object with the result of this message, the output parameters.  Such a request is called method in D-Bus.

The other form of communication are signals.  The underlying message is emitted from an object and will be received by all other applications which have registered for such a signal.

All methods and signals an object supports are called interface of the object.  Interfaces are specified under a hierarchical name in D-Bus; an object can support several interfaces.  Such an interface name could be org.gnu.Emacs.TextEditor or org.gnu.Emacs.FileManager.

Inspection of D-Bus services.
*****************************

D-Bus version.
==============

D-Bus has evolved over the years.  New features have been added with new D-Bus versions.  There are two variables, which allow the determination of the D-Bus version used.

 -- Variable: dbus-compiled-version
     This variable, a string, determines the version of D-Bus Emacs is compiled against.  If it cannot be determined the value is nil.

 -- Variable: dbus-runtime-version
     The other D-Bus version to be checked is the version of D-Bus Emacs runs with.  This string can be different from dbus-compiled-version. It is also nil, if it cannot be determined at runtime.

Bus names.
==========

There are several basic functions which inspect the buses for registered names.  Internally they use the basic interface org.freedesktop.DBus, which is supported by all objects of a bus.

 -- Function: dbus-list-activatable-names &optional bus
     This function returns the D-Bus service names, which can be activated for BUS.  It must be either the keyword :system (the default) or the keyword :session.  An activatable service is described in a service registration file.  Under GNU/Linux, such files are located at /usr/share/dbus-1/system-services/ (for the :system bus) or /usr/share/dbus-1/services/.  An activatable service is not necessarily registered at BUS already.

     The result is a list of strings, which is nil when there are no activatable service names at all.  Example:

          ;; Check, whether the document viewer can be accessed via D-Bus.
          (member "org.gnome.evince.Daemon"
                  (dbus-list-activatable-names :session))

 -- Function: dbus-list-names bus
     This function returns all service names, which are registered at D-Bus BUS.  The result is a list of strings, which is nil when there are no registered service names at all.  Well known names are strings like org.freedesktop.DBus.  Names starting with : are unique names for services.

     BUS must be either the keyword :system or the keyword :session.

 -- Function: dbus-list-known-names bus
     This function retrieves all registered services which correspond to a known name in BUS.  A service has a known name if it doesn't start with :.  The result is a list of strings, which is nil when there are no known names at all.

     BUS must be either the keyword :system or the keyword :session.

 -- Function: dbus-list-queued-owners bus service
     For a given service, registered at D-Bus BUS under the name SERVICE, this function returns all queued unique names.  The result is a list of strings, or nil when there are no queued names for SERVICE at all.

     BUS must be either the keyword :system or the keyword :session.  SERVICE must be a known service name as string.

 -- Function: dbus-get-name-owner bus service
     For a given service, registered at D-Bus BUS under the name SERVICE, this function returns the unique name of the name owner.  The result is a string, or nil when there is no name owner of SERVICE.

     BUS must be either the keyword :system or the keyword :session.  SERVICE must be a known service name as string.

 -- Function: dbus-ping bus service &optional timeout
     This function checks whether the service name SERVICE is registered at D-Bus BUS.  If SERVICE has not yet started, it is autostarted if possible.  The result is either t or nil.

     BUS must be either the keyword :system or the keyword :session.  SERVICE must be a string.  TIMEOUT, a nonnegative integer, specifies the maximum number of milliseconds before dbus-ping must return.  The default value is 25,000. Example:

          (message
           "%s screensaver on board."
           (cond
            ((dbus-ping :session "org.gnome.ScreenSaver" 100) "Gnome")
            ((dbus-ping :session "org.freedesktop.ScreenSaver" 100) "KDE")
            (t "No")))

     To check whether SERVICE is already running without autostarting it, you can instead write:

          (member service (dbus-list-known-names bus))

 -- Function: dbus-get-unique-name bus
     This function returns the unique name, under which Emacs is registered at D-Bus BUS, as a string.

     BUS must be either the keyword :system or the keyword :session.

Knowing the details of D-Bus services.
======================================

D-Bus services publish their interfaces.  This can be retrieved and analyzed during runtime, in order to understand the used implementation.

The resulting introspection data are in XML format.  The root introspection element is always a node element.  It might have a name attribute, which denotes the (absolute) object path an interface is introspected.

The root node element may have node and interface children.  A child node element must have a name attribute, this case it is the relative object path to the root node element.

An interface element has just one attribute, name, which is the full name of that interface.  The default interface org.freedesktop.DBus.Introspectable is always present.  Example:

     <node name="/org/bluez">
       <interface name="org.freedesktop.DBus.Introspectable">
         ...
       </interface>
       <interface name="org.bluez.Manager">
         ...
       </interface>
       <interface name="org.bluez.Database">
         ...
       </interface>
       <interface name="org.bluez.Security">
         ...
       </interface>
       <node name="service_audio"/>
       <node name="service_input"/>
       <node name="service_network"/>
       <node name="service_serial"/>
     </node>

Children of an interface element can be method, signal and property elements.  A method element stands for a D-Bus method of the surrounding interface.  The element itself has a name attribute, showing the method name.  Children elements arg stand for the arguments of a method.  Example:

     <method name="ResolveHostName">
       <arg name="interface" type="i" direction="in"/>
       <arg name="protocol" type="i" direction="in"/>
       <arg name="name" type="s" direction="in"/>
       <arg name="aprotocol" type="i" direction="in"/>
       <arg name="flags" type="u" direction="in"/>
       <arg name="interface" type="i" direction="out"/>
       <arg name="protocol" type="i" direction="out"/>
       <arg name="name" type="s" direction="out"/>
       <arg name="aprotocol" type="i" direction="out"/>
       <arg name="address" type="s" direction="out"/>
       <arg name="flags" type="u" direction="out"/>
     </method>

arg elements can have the attributes name, type and direction.  The name attribute is optional.  The type attribute stands for the signature of the argument in D-Bus.  For a discussion of D-Bus types and their Lisp representation see Type Conversion. (D-Bus signatures are explained in the D-Bus specification https://dbus.freedesktop.org/doc/dbus-specification.html#message-protocol-signatures.) The direction attribute of an arg element can be only in or out; in case it is omitted, it defaults to in.

A signal element of an interface has a similar structure.  The direction attribute of an arg child element can be only out here; which is also the default value. Example:

     <signal name="StateChanged">
       <arg name="state" type="i"/>
       <arg name="error" type="s"/>
     </signal>

A property element has no arg child element.  It just has the attributes name, type and access, which are all mandatory.  The access attribute allows the values readwrite, read, and write. Example:

     <property name="Status" type="u" direction="read"/>

annotation elements can be children of interface, method, signal, and property elements.  Unlike properties, which can change their values during lifetime of a D-Bus object, annotations are static.  Often they are used for code generators of D-Bus language bindings.  Example:

     <annotation name="de.berlios.Pinot.GetStatistics" value="pinotDBus"/>

Annotations have just name and value attributes, both must be strings.

 -- Function: dbus-introspect bus service path
     This function returns all interfaces and sub-nodes of SERVICE, registered at object path PATH at bus BUS.

     BUS must be either the keyword :system or the keyword :session.  SERVICE must be a known service name, and PATH must be a valid object path.  The last two parameters are strings.  The result, the introspection data, is a string in XML format.  Example:

          (dbus-introspect
           :system "org.freedesktop.Hal"
           "/org/freedesktop/Hal/devices/computer")

          => "<!DOCTYPE node PUBLIC
              "-//freedesktop//DTD D-BUS Object Introspection 1.0//EN"
              "http://www.freedesktop.org/standards/dbus/1.0/introspect.dtd">
              <node>
                <interface name="org.freedesktop.Hal.Device">
                  <method name="GetAllProperties">
                    <arg name="properties" direction="out" type="a{sv}"/>
                  </method>
                  ...
                  <signal name="PropertyModified">
                    <arg name="num_updates" type="i"/>
                    <arg name="updates" type="a(sbb)"/>
                  </signal>
                </interface>
                ...
              </node>"

     This example informs us, that the service org.freedesktop.Hal at object path /org/freedesktop/Hal/devices/computer offers the interface org.freedesktop.Hal.Device (and 2 other interfaces not documented here).  This interface contains the method GetAllProperties, which needs no input parameters, but returns as output parameter an array of dictionary entries (key-value pairs). Every dictionary entry has a string as key, and a variant as value.

     The interface offers also a signal, which returns 2 parameters: an integer, and an array consisting of elements which are a struct of a string and 2 boolean values. (The interfaces of the service org.freedesktop.Hal are described in the HAL specification (https://people.freedesktop.org/~dkukawka/hal-spec-git/hal-spec.html#interfaces).)

 -- Function: dbus-introspect-xml bus service path
     This function serves a similar purpose to the function dbus-introspect.  The returned value is a parsed XML tree, which can be used for further analysis.  Example:

          (dbus-introspect-xml
           :session "org.freedesktop.xesam.searcher"
           "/org/freedesktop/xesam/searcher/main")

          => (node ((name . "/org/freedesktop/xesam/searcher/main"))
              (interface ((name . "org.freedesktop.xesam.Search"))
                (method ((name . "GetHitData"))
                  (arg ((name . "search")
                        (type . "s")
                        (direction . "in")))
                  (arg ((name . "hit_ids")
                        (type . "au")
                        (direction . "in")))
                  (arg ((name . "fields")
                        (type . "as")
                        (direction . "in")))
                  (arg ((name . "hit_data")
                        (type . "aav")
                        (direction . "out"))))
                ...
                (signal ((name . "HitsAdded"))
                  (arg ((name . "search") (type . "s")))
                  (arg ((name . "count") (type . "u")))))
              ...)

 -- Function: dbus-introspect-get-attribute object attribute
     This function returns the ATTRIBUTE value of a D-Bus introspection OBJECT.  The value of OBJECT can be any subtree of a parsed XML tree as retrieved with dbus-introspect-xml.  ATTRIBUTE must be a string according to the attribute names in the D-Bus specification.  Example:

          (dbus-introspect-get-attribute
           (dbus-introspect-xml
            :system "org.freedesktop.SystemToolsBackends"
            "/org/freedesktop/SystemToolsBackends/UsersConfig")
           "name")

          => "/org/freedesktop/SystemToolsBackends/UsersConfig"

     If OBJECT has no ATTRIBUTE, the function returns nil.

Detecting object paths and interfaces.
======================================

The first elements, to be introspected for a D-Bus object, are further object paths and interfaces.

 -- Function: dbus-introspect-get-node-names bus service path
     This function returns all node names of SERVICE in D-Bus BUS at object path PATH as a list of strings.  Example:

          (dbus-introspect-get-node-names
           :session "org.gnome.seahorse" "/org/gnome/seahorse")

          => ("crypto" "keys")

     The node names stand for further object paths of the D-Bus SERVICE, relative to PATH.  In the example, /org/gnome/seahorse/crypto and /org/gnome/seahorse/keys are also object paths of the D-Bus service org.gnome.seahorse.

 -- Function: dbus-introspect-get-all-nodes bus service path
     This function returns all node names of SERVICE in D-Bus BUS at object path PATH.  It returns a list of strings with all object paths of SERVICE, starting at PATH. Example:

          (dbus-introspect-get-all-nodes :session "org.gnome.seahorse" "/")

          => ("/" "/org" "/org/gnome" "/org/gnome/seahorse"
              "/org/gnome/seahorse/crypto"
              "/org/gnome/seahorse/keys"
              "/org/gnome/seahorse/keys/openpgp"
              "/org/gnome/seahorse/keys/openpgp/local"
              "/org/gnome/seahorse/keys/openssh"
              "/org/gnome/seahorse/keys/openssh/local")

 -- Function: dbus-introspect-get-interface-names bus service path
     This function returns a list strings of all interface names of SERVICE in D-Bus BUS at object path PATH.  This list will contain the default interface org.freedesktop.DBus.Introspectable.

     Another default interface is org.freedesktop.DBus.Properties. If present, interface elements can also have property children.  Example:

          (dbus-introspect-get-interface-names
           :system "org.freedesktop.Hal"
           "/org/freedesktop/Hal/devices/computer")

          => ("org.freedesktop.DBus.Introspectable"
              "org.freedesktop.Hal.Device"
              "org.freedesktop.Hal.Device.SystemPowerManagement"
              "org.freedesktop.Hal.Device.CPUFreq")

 -- Function: dbus-introspect-get-interface bus service path interface
     This function returns INTERFACE of SERVICE in D-Bus BUS at object path PATH.  The return value is an XML element.  INTERFACE must be a string and a member of the list returned by dbus-introspect-get-interface-names.  Example:

          (dbus-introspect-get-interface
           :session "org.freedesktop.xesam.searcher"
           "/org/freedesktop/xesam/searcher/main"
           "org.freedesktop.xesam.Search")

          => (interface ((name . "org.freedesktop.xesam.Search"))
               (method ((name . "GetHitData"))
                 (arg ((name . "search") (type . "s") (direction . "in")))
                 (arg ((name . "hit_ids") (type . "au") (direction . "in")))
                 (arg ((name . "fields") (type . "as") (direction . "in")))
                 (arg ((name . "hit_data") (type . "aav") (direction . "out"))))
               ...
               (signal ((name . "HitsAdded"))
                 (arg ((name . "search") (type . "s")))
                 (arg ((name . "count") (type . "u")))))

With these functions, it is possible to retrieve all introspection data from a running system:

     (progn
       (pop-to-buffer "*introspect*")
       (erase-buffer)
       (dolist (service (dbus-list-known-names :session))
         (dolist (path (dbus-introspect-get-all-nodes :session service "/"))
           ;; We want to introspect only elements, which have more than
           ;; the default interface "org.freedesktop.DBus.Introspectable".
           (when (delete
                  "org.freedesktop.DBus.Introspectable"
                  (dbus-introspect-get-interface-names :session service path))
             (insert (format "\nservice: \"%s\" path: \"%s\"\n" service path)
                     (dbus-introspect :session service path))
             (redisplay t)))))

Applying the functionality.
===========================

Methods and signals are the communication means to D-Bus.  The following functions return their specifications.

 -- Function: dbus-introspect-get-method-names bus service path interface
     This function returns a list of strings of all method names of INTERFACE of SERVICE in D-Bus BUS at object path PATH.  Example:

          (dbus-introspect-get-method-names
           :session "org.freedesktop.xesam.searcher"
           "/org/freedesktop/xesam/searcher/main"
           "org.freedesktop.xesam.Search")

          => ("GetState" "StartSearch" "GetHitCount" "GetHits" "NewSession"
              "CloseSession" "GetHitData" "SetProperty" "NewSearch"
              "GetProperty" "CloseSearch")

 -- Function: dbus-introspect-get-method bus service path interface method
     This function returns METHOD of INTERFACE as an XML element.  It must be located at SERVICE in D-Bus BUS at object path PATH.  METHOD must be a string and a member of the list returned by dbus-introspect-get-method-names. Example:

          (dbus-introspect-get-method
           :session "org.freedesktop.xesam.searcher"
           "/org/freedesktop/xesam/searcher/main"
           "org.freedesktop.xesam.Search" "GetHitData")

          => (method ((name . "GetHitData"))
               (arg ((name . "search") (type . "s") (direction . "in")))
               (arg ((name . "hit_ids") (type . "au") (direction . "in")))
               (arg ((name . "fields") (type . "as") (direction . "in")))
               (arg ((name . "hit_data") (type . "aav") (direction . "out"))))

 -- Function: dbus-introspect-get-signal-names bus service path interface
     This function returns a list of strings of all signal names of INTERFACE of SERVICE in D-Bus BUS at object path PATH.  Example:

          (dbus-introspect-get-signal-names
           :session "org.freedesktop.xesam.searcher"
           "/org/freedesktop/xesam/searcher/main"
           "org.freedesktop.xesam.Search")

          => ("StateChanged" "SearchDone" "HitsModified"
              "HitsRemoved" "HitsAdded")

 -- Function: dbus-introspect-get-signal bus service path interface signal
     This function returns SIGNAL of INTERFACE as an XML element.  It must be located at SERVICE in D-Bus BUS at object path PATH.  SIGNAL must be a string and a member of the list returned by dbus-introspect-get-signal-names. Example:

          (dbus-introspect-get-signal
           :session "org.freedesktop.xesam.searcher"
           "/org/freedesktop/xesam/searcher/main"
           "org.freedesktop.xesam.Search" "HitsAdded")

          => (signal ((name . "HitsAdded"))
               (arg ((name . "search") (type . "s")))
               (arg ((name . "count") (type . "u"))))

What else to know about interfaces.
===================================

Interfaces can have properties.  These can be exposed via the org.freedesktop.DBus.Properties interface (See https://dbus.freedesktop.org/doc/dbus-specification.html#standard-interfaces-properties). That is, properties can be retrieved and changed during the lifetime of an element.

A generalized interface is org.freedesktop.DBus.Objectmanager (See https://dbus.freedesktop.org/doc/dbus-specification.html#standard-interfaces-objectmanager), which returns objects, their interfaces and properties for a given service in just one call.

Annotations, on the other hand, are static values for an element. Often, they are used to instruct generators, how to generate code from the interface for a given language binding.

 -- Function: dbus-introspect-get-property-names bus service path interface
     This function returns a list of strings with all property names of INTERFACE of SERVICE in D-Bus BUS at object path PATH.  Example:

          (dbus-introspect-get-property-names
           :session "org.kde.kded" "/modules/networkstatus"
           "org.kde.Solid.Networking.Client")

          => ("Status")

     If an interface declares properties, the corresponding element supports also the org.freedesktop.DBus.Properties interface.

 -- Function: dbus-introspect-get-property bus service path interface property
     This function returns PROPERTY of INTERFACE as an XML element.  It must be located at SERVICE in D-Bus BUS at object path PATH.  PROPERTY must be a string and a member of the list returned by dbus-introspect-get-property-names.

     A PROPERTY value can be retrieved by the function dbus-introspect-get-attribute.  Example:

          (dbus-introspect-get-property
           :session "org.kde.kded" "/modules/networkstatus"
           "org.kde.Solid.Networking.Client" "Status")

          => (property ((access . "read") (type . "u") (name . "Status")))

          (dbus-introspect-get-attribute
           (dbus-introspect-get-property
            :session "org.kde.kded" "/modules/networkstatus"
            "org.kde.Solid.Networking.Client" "Status")
           "access")

          => "read"

 -- Function: dbus-get-property bus service path interface property
     This function returns the value of PROPERTY of INTERFACE. It will be checked at BUS, SERVICE, PATH.  The result can be any valid D-Bus value.  If there is no PROPERTY, or PROPERTY cannot be read, an error is raised.  Example:

          (dbus-get-property
           :session "org.kde.kded" "/modules/networkstatus"
           "org.kde.Solid.Networking.Client" "Status")

          => 4

 -- Function: dbus-set-property bus service path interface property [type] value
     This function sets the value of PROPERTY of INTERFACE to VALUE.  It will be checked at BUS, SERVICE, PATH.  VALUE can be preceded by a TYPE keyword. When the value is successfully set, this function returns VALUE. Example:

          (dbus-set-property
           :session "org.kde.kaccess" "/MainApplication"
           "com.trolltech.Qt.QApplication" "doubleClickInterval" :uint16 500)

          => 500

 -- Function: dbus-get-all-properties bus service path interface
     This function returns all readable properties of INTERFACE.  It will be checked at BUS, SERVICE, PATH.  The result is a list of cons cells.  Every cons cell contains the name of the property, and its value.  If there are no properties, nil is returned.  Example:

          (dbus-get-all-properties
           :session "org.kde.kaccess" "/MainApplication"
           "com.trolltech.Qt.QApplication")

          => (("cursorFlashTime" . 1000) ("doubleClickInterval" . 500)
              ("keyboardInputInterval" . 400) ("wheelScrollLines" . 3)
              ("globalStrut" 0 0) ("startDragTime" . 500)
              ("startDragDistance" . 4) ("quitOnLastWindowClosed" . t)
              ("styleSheet" . ""))

 -- Function: dbus-get-all-managed-objects bus service path
     This function returns all objects at BUS, SERVICE, PATH, and the children of PATH.  The result is a list of objects.  Every object is a cons cell of an existing path name, and the list of available interface objects.  An interface object is another cons, whose car is the interface name and cdr is the list of properties as returned by dbus-get-all-properties for that path and interface.  Example:

          (dbus-get-all-managed-objects
           :session "org.gnome.SettingsDaemon" "/")

          => (("/org/gnome/SettingsDaemon/Power"
               ("org.gnome.SettingsDaemon.Power.Keyboard")
               ("org.gnome.SettingsDaemon.Power.Screen")
               ("org.gnome.SettingsDaemon.Power"
                ("Icon" . ". GThemedIcon battery-full-charged-symbolic ")
                ("Tooltip" . "Laptop battery is charged"))
               ("org.freedesktop.DBus.Peer")
               ("org.freedesktop.DBus.Introspectable")
               ("org.freedesktop.DBus.Properties")
               ("org.freedesktop.DBus.ObjectManager"))
              ...)

     If possible, org.freedesktop.DBus.ObjectManager.GetManagedObjects is used for retrieving the information.  Otherwise, the information is collected via org.freedesktop.DBus.Introspectable.Introspect and org.freedesktop.DBus.Properties.GetAll, which is slow.

     An overview of all existing object paths, their interfaces and properties could be retrieved by the following code:

          (let ((result (mapcar (lambda (service)
                                  (cons service
                                        (dbus-get-all-managed-objects
                                         :session service "/")))
                                (dbus-list-known-names :session))))
            (pop-to-buffer "*objectmanager*")
            (erase-buffer)
            (pp result (current-buffer)))

 -- Function: dbus-introspect-get-annotation-names bus service path interface &optional name
     This function returns a list of all annotation names as list of strings.  If NAME is nil, the annotations are children of INTERFACE, otherwise NAME must be a method, signal, or property XML element, where the annotations belong to.  Example:

          (dbus-introspect-get-annotation-names
           :session "de.berlios.Pinot" "/de/berlios/Pinot"
           "de.berlios.Pinot" "GetStatistics")

          => ("de.berlios.Pinot.GetStatistics")

     Default annotation names (See https://dbus.freedesktop.org/doc/dbus-specification.html#introspection-format) are

     org.freedesktop.DBus.Deprecated
          Whether or not the entity is deprecated; defaults to nil

     org.freedesktop.DBus.GLib.CSymbol
          The C symbol; may be used for methods and interfaces

     org.freedesktop.DBus.Method.NoReply
          If set, don't expect a reply to the method call; defaults to nil

 -- Function: dbus-introspect-get-annotation bus service path interface name annotation
     This function returns ANNOTATION as an XML object.  If NAME is nil, ANNOTATION is a child of INTERFACE, otherwise NAME must be the name of a method, signal, or property XML element, where the ANNOTATION belongs to.

     An attribute value can be retrieved by dbus-introspect-get-attribute.  Example:

          (dbus-introspect-get-annotation
           :session "de.berlios.Pinot" "/de/berlios/Pinot"
           "de.berlios.Pinot" "GetStatistics"
           "de.berlios.Pinot.GetStatistics")

          => (annotation ((name . "de.berlios.Pinot.GetStatistics")
                          (value . "pinotDBus")))

          (dbus-introspect-get-attribute
           (dbus-introspect-get-annotation
            :session "de.berlios.Pinot" "/de/berlios/Pinot"
            "de.berlios.Pinot" "GetStatistics"
            "de.berlios.Pinot.GetStatistics")
           "value")

          => "pinotDBus"

The final details.
==================

Methods and signals have arguments.  They are described in the arg XML elements.

 -- Function: dbus-introspect-get-argument-names bus service path interface name
     This function returns a list of all argument names as strings. NAME must be a method or signal XML element. Example:

          (dbus-introspect-get-argument-names
           :session "org.freedesktop.xesam.searcher"
           "/org/freedesktop/xesam/searcher/main"
           "org.freedesktop.xesam.Search" "GetHitData")

          => ("search" "hit_ids" "fields" "hit_data")

     Argument names are optional; the function can therefore return nil, even if the method or signal has arguments.

 -- Function: dbus-introspect-get-argument bus service path interface name arg
     This function returns the argument ARG as an XML object. NAME must be a method or signal XML element. Example:

          (dbus-introspect-get-argument
           :session "org.freedesktop.xesam.searcher"
           "/org/freedesktop/xesam/searcher/main"
           "org.freedesktop.xesam.Search" "GetHitData" "search")

          => (arg ((name . "search") (type . "s") (direction . "in")))

 -- Function: dbus-introspect-get-signature bus service path interface name &optional direction
     This function returns the signature of a method or signal, represented by NAME, as a string.

     If NAME is a method, DIRECTION can be either in or out.  If DIRECTION is nil, in is assumed.

     If NAME is a signal, and DIRECTION is non-nil, DIRECTION must be out.  Example:

          (dbus-introspect-get-signature
           :session "org.freedesktop.xesam.searcher"
           "/org/freedesktop/xesam/searcher/main"
           "org.freedesktop.xesam.Search" "GetHitData" "in")

          => "sauas"

          (dbus-introspect-get-signature
           :session "org.freedesktop.xesam.searcher"
           "/org/freedesktop/xesam/searcher/main"
           "org.freedesktop.xesam.Search" "HitsAdded")

          => "su"

Mapping Lisp types and D-Bus types.
***********************************

D-Bus method calls and signals accept usually several arguments as parameters, either as input parameter, or as output parameter.  Every argument belongs to a D-Bus type.

Such arguments must be mapped between the value encoded as a D-Bus type, and the corresponding type of Lisp objects.  The mapping is applied Lisp object ==> D-Bus type for input parameters, and D-Bus type ==> Lisp object for output parameters.

Input parameters.
=================

Input parameters for D-Bus methods and signals occur as arguments of a Lisp function call.  The following mapping to D-Bus types is applied, when the corresponding D-Bus message is created:

     Lisp type                                D-Bus type

     t and nil   ==>   DBUS_TYPE_BOOLEAN
     natural number            ==>   DBUS_TYPE_UINT32
     negative integer          ==>   DBUS_TYPE_INT32
     float                     ==>   DBUS_TYPE_DOUBLE
     string                    ==>   DBUS_TYPE_STRING
     list                      ==>   DBUS_TYPE_ARRAY

Other Lisp objects, like symbols or hash tables, are not accepted as input parameters.

If it is necessary to use another D-Bus type, a corresponding type keyword can be prepended to the corresponding Lisp object.  Basic D-Bus types are represented by the type keywords :byte, :boolean, :int16, :uint16, :int32, :uint32, :int64, :uint64, :double, :string, :object-path, :signature and :unix-fd.

Example:

     (dbus-call-method ... NAT-NUMBER STRING)

is equivalent to

     (dbus-call-method ... :uint32 NAT-NUMBER :string STRING)

but different to

     (dbus-call-method ... :int32 NAT-NUMBER :signature STRING)

The value for a D-Bus byte type can be any natural number.  If the number is larger than 255, it is truncated to the least significant byte.  For example, :byte 1025 is equal to :byte 1.  If a character is used as argument, modifiers represented outside this range are stripped off.  For example, :byte ?x is equal to :byte ?\M-x, but it is not equal to :byte ?\C-x or :byte ?\M-\C-x.

Signed and unsigned D-Bus integer types expect a corresponding integer value.  A unix file descriptor is restricted to the values 0...9.

If typed explicitly, a non-nil boolean value like :boolean 'symbol is handled like t or :boolean t.

A D-Bus compound type is always represented as a list.  The CAR of this list can be the type keyword :array, :variant, :struct or :dict-entry, which would result in a corresponding D-Bus container.  :array is optional, because this is the default compound D-Bus type for a list.

The objects being elements of the list are checked according to the D-Bus compound type rules.

  * An array must contain only elements of the same D-Bus type.  It can be empty.

  * A variant must contain only a single element.

  * A dictionary entry must be an element of an array, and it must contain only a key-value pair of two elements, with a basic D-Bus type key.

  * There are no restrictions for structs.

If an empty array needs an element D-Bus type other than string, it can contain exactly one element of D-Bus type :signature.  The value of this element (a string) is used as the signature of the elements of this array.  Example:

     (dbus-call-method
      :session "org.freedesktop.Notifications"
      "/org/freedesktop/Notifications"
      "org.freedesktop.Notifications" "Notify"
      "GNU Emacs"                   ; Application name.
      0                             ; No replacement of other notifications.
      ""                            ; No icon.
      "Notification summary"        ; Summary.
      (format                       ; Body.
       "This is a test notification, raised from\n%S" (emacs-version))
      '(:array)                     ; No actions (empty array of strings).
      '(:array :signature "{sv}")   ; No hints
                                    ; (empty array of dictionary entries).
      :int32 -1)                    ; Default timeout.

     => 3

 -- Function: dbus-string-to-byte-array string
     Sometimes, D-Bus methods require as input parameter an array of bytes, instead of a string.  This function converts STRING into an array of bytes of the UTF-8 encoding of STRING.  Example:

          (dbus-string-to-byte-array "/etc/hosts")

          => (:array :byte 47 :byte 101 :byte 116 :byte 99 :byte 47
                     :byte 104 :byte 111 :byte 115 :byte 116 :byte 115)

 -- Function: dbus-escape-as-identifier string
     This function escapes an arbitrary STRING so it follows the rules for a C identifier.  The escaped string can be used as object path component, interface element component, bus name component or member name in D-Bus.

     The escaping consists of replacing all non-alphanumerics, and the first character if it's a digit, with an underscore and two lower-case hex digits.  As a special case, "" is escaped to "_".  Example:

          (dbus-escape-as-identifier "0123abc_xyz\x01\xff")

          => "_30123abc_5fxyz_01_ff"

Output parameters.
==================

Output parameters of D-Bus methods and signals are mapped to Lisp objects.

     D-Bus type                             Lisp type

     DBUS_TYPE_BOOLEAN       ==>   t or nil
     DBUS_TYPE_BYTE          ==>   natural number
     DBUS_TYPE_UINT16        ==>   natural number
     DBUS_TYPE_INT16         ==>   integer
     DBUS_TYPE_UINT32        ==>   natural number
     DBUS_TYPE_UNIX_FD       ==>   natural number
     DBUS_TYPE_INT32         ==>   integer
     DBUS_TYPE_UINT64        ==>   natural number
     DBUS_TYPE_INT64         ==>   integer
     DBUS_TYPE_DOUBLE        ==>   float
     DBUS_TYPE_STRING        ==>   string
     DBUS_TYPE_OBJECT_PATH   ==>   string
     DBUS_TYPE_SIGNATURE     ==>   string
     DBUS_TYPE_ARRAY         ==>   list
     DBUS_TYPE_VARIANT       ==>   list
     DBUS_TYPE_STRUCT        ==>   list
     DBUS_TYPE_DICT_ENTRY    ==>   list

The resulting list of the last 4 D-Bus compound types contains as elements the elements of the D-Bus container, mapped according to the same rules.

The signal PropertyModified, discussed as an example in Inspection, would offer as Lisp data the following object (BOOL stands here for either nil or t):

     (INTEGER ((STRING BOOL BOOL) (STRING BOOL BOOL) ...))

 -- Function: dbus-byte-array-to-string byte-array
     If a D-Bus method or signal returns an array of bytes, which are known to represent a UTF-8 string, this function converts BYTE-ARRAY to the corresponding Lisp string.  The contents of BYTE-ARRAY should be the byte sequence of a UTF-8 encoded string.  Example:

          (dbus-byte-array-to-string '(47 101 116 99 47 104 111 115 116 115))

          => "/etc/hosts"

 -- Function: dbus-unescape-from-identifier string
     This function retrieves the original string from the encoded STRING as a unibyte string.  The value of STRING must have been encoded with dbus-escape-as-identifier.  Example:

          (dbus-unescape-from-identifier "_30123abc_5fxyz_01_ff")

          => "0123abc_xyz\x01\xff"

     If the original string used in dbus-escape-as-identifier is a multibyte string, it cannot be expected that this function returns that string:

          (string-equal
           (dbus-unescape-from-identifier
            (dbus-escape-as-identifier "Grüß Göttin"))
           "Grüß Göttin")

          => nil

Calling methods in a blocking way.
**********************************

Methods can be called synchronously (blocking) or asynchronously (non-blocking).

At the D-Bus level, a method call consist of two messages: one message which carries the input parameters to the object owning the method to be called, and a reply message returning the resulting output parameters from the object.

 -- Function: dbus-call-method bus service path interface method &optional :timeout timeout &rest args
     This function calls METHOD on the D-Bus BUS.  BUS is either the keyword :system or the keyword :session.

     SERVICE is the D-Bus service name to be used.  PATH is the D-Bus object path, SERVICE is registered at.  INTERFACE is an interface offered by SERVICE.  It must provide METHOD.

     If the parameter :timeout is given, the following integer TIMEOUT specifies the maximum number of milliseconds before the method call must return.  The default value is 25,000.  If the method call doesn't return in time, a D-Bus error is raised (see Errors and Events).

     The remaining arguments ARGS are passed to METHOD as arguments.  They are converted into D-Bus types as described in Type Conversion.

     The function returns the resulting values of METHOD as a list of Lisp objects, according to the type conversion rules described in Type Conversion.  Example:

          (dbus-call-method
           :session "org.gnome.seahorse" "/org/gnome/seahorse/keys/openpgp"
           "org.gnome.seahorse.Keys" "GetKeyField"
           "openpgp:657984B8C7A966DD" "simple-name")

          => (t ("Philip R. Zimmermann"))

     If the result of the method call is just one value, the converted Lisp object is returned instead of a list containing this single Lisp object.  Example:

          (dbus-call-method
           :system "org.freedesktop.Hal"
           "/org/freedesktop/Hal/devices/computer"
           "org.freedesktop.Hal.Device" "GetPropertyString"
           "system.kernel.machine")

          => "i686"

     With the dbus-introspect function it is possible to explore the interfaces of org.freedesktop.Hal service.  It offers the interfaces org.freedesktop.Hal.Manager for the object at the path /org/freedesktop/Hal/Manager as well as the interface org.freedesktop.Hal.Device for all objects prefixed with the path /org/freedesktop/Hal/devices.  With the methods GetAllDevices and GetAllProperties, it is simple to emulate the lshal command on GNU/Linux systems:

          (dolist (device
                   (dbus-call-method
                    :system "org.freedesktop.Hal"
                    "/org/freedesktop/Hal/Manager"
                    "org.freedesktop.Hal.Manager" "GetAllDevices"))
            (message "\nudi = %s" device)
            (dolist (properties
                     (dbus-call-method
                      :system "org.freedesktop.Hal" device
                      "org.freedesktop.Hal.Device" "GetAllProperties"))
              (message "  %s = %S"
                       (car properties) (or (caadr properties) ""))))

          -| "udi = /org/freedesktop/Hal/devices/computer
                info.addons = (\"hald-addon-acpi\")
                info.bus = \"unknown\"
                info.product = \"Computer\"
                info.subsystem = \"unknown\"
                info.udi = \"/org/freedesktop/Hal/devices/computer\"
                linux.sysfs_path_device = \"(none)\"
                power_management.acpi.linux.version = \"20051216\"
                power_management.can_suspend_to_disk = t
                power_management.can_suspend_to_ram = \"\"
                power_management.type = \"acpi\"
                smbios.bios.release_date = \"11/07/2001\"
                system.chassis.manufacturer = \"COMPAL\"
                system.chassis.type = \"Notebook\"
                system.firmware.release_date = \"03/19/2005\"
                ..."

Calling methods non-blocking.
*****************************

 -- Function: dbus-call-method-asynchronously bus service path interface method handler &optional :timeout timeout &rest args
     This function calls METHOD on the D-Bus BUS asynchronously.  BUS is either the keyword :system or the keyword :session.

     SERVICE is the D-Bus service name to be used.  PATH is the D-Bus object path, SERVICE is registered at.  INTERFACE is an interface offered by SERVICE.  It must provide METHOD.

     HANDLER is a Lisp function, which is called when the corresponding return message arrives.  If HANDLER is nil, no return message will be expected.

     If the parameter :timeout is given, the following integer TIMEOUT specifies the maximum number of milliseconds before a reply message must arrive.  The default value is 25,000.  If there is no reply message in time, a D-Bus error is raised (see Errors and Events).

     The remaining arguments ARGS are passed to METHOD as arguments.  They are converted into D-Bus types as described in Type Conversion.

     If HANDLER is a Lisp function, the function returns a key into the hash table dbus-registered-objects-table.  The corresponding entry in the hash table is removed, when the return message arrives, and HANDLER is called.  Example:

          (dbus-call-method-asynchronously
           :system "org.freedesktop.Hal"
           "/org/freedesktop/Hal/devices/computer"
           "org.freedesktop.Hal.Device" "GetPropertyString"
           (lambda (msg) (message "%s" msg))
           "system.kernel.machine")

          -| i686

          => (:serial :system 2)

Offering own services.
**********************

You can offer an own service in D-Bus, which will be visible by other D-Bus clients.  See https://dbus.freedesktop.org/doc/dbus-api-design.html for a discussion of the design.

In order to register methods on the D-Bus, Emacs has to request a well known name on the D-Bus under which it will be available for other clients.  Names on the D-Bus can be registered and unregistered using the following functions:

 -- Function: dbus-register-service bus service &rest flags
     This function registers the known name SERVICE on D-Bus BUS.

     BUS is either the keyword :system or the keyword :session.

     SERVICE is the service name to be registered on the D-Bus.  It must be a known name.

     FLAGS is a subset of the following keywords:

     :allow-replacement
          Allow another service to become the primary owner if requested.

     :replace-existing
          Request to replace the current primary owner.

     :do-not-queue
          If we can not become the primary owner do not place us in the queue.

     One of the following keywords is returned:

     :primary-owner
          We have become the primary owner of the name SERVICE.

     :in-queue
          We could not become the primary owner and have been placed in the queue.

     :exists
          We already are in the queue.

     :already-owner
          We already are the primary owner.

 -- Function: dbus-unregister-service bus service
     This function unregisters all objects from D-Bus BUS, that were registered by Emacs for SERVICE.

     BUS is either the keyword :system or the keyword :session.

     SERVICE is the D-Bus service name of the D-Bus.  It must be a known name.  Emacs releases its association to SERVICE from D-Bus.

     One of the following keywords is returned:

     :released
          We successfully released the name SERVICE.

     :non-existent
          The name SERVICE does not exist on the bus.

     :not-owner
          We are not an owner of the name SERVICE.

     When SERVICE is not a known name but a unique name, the function returns nil.

When a name has been chosen, Emacs can offer its own methods, which can be called by other applications.  These methods could be an implementation of an interface of a well known service, like org.freedesktop.TextEditor.

They could also be an implementation of its own interface.  In this case, the service name must be org.gnu.Emacs.  The object path shall begin with /org/gnu/Emacs/APPLICATION, and the interface name shall be org.gnu.Emacs.APPLICATION, where APPLICATION is the name of the application which provides the interface.

 -- Constant: dbus-service-emacs
     The well known service name org.gnu.Emacs of Emacs.

 -- Constant: dbus-path-emacs
     The object path namespace /org/gnu/Emacs used by Emacs.

 -- Constant: dbus-interface-emacs
     The interface namespace org.gnu.Emacs used by Emacs.

 -- Function: dbus-register-method bus service path interface method handler dont-register-service
     With this function, an application registers METHOD on the D-Bus BUS.

     BUS is either the keyword :system or the keyword :session.

     SERVICE is the D-Bus service name of the D-Bus object METHOD is registered for.  It must be a known name (see discussion of DONT-REGISTER-SERVICE below).

     PATH is the D-Bus object path SERVICE is registered (see discussion of DONT-REGISTER-SERVICE below).

     INTERFACE is the interface offered by SERVICE.  It must provide METHOD.

     HANDLER is a Lisp function to be called when a METHOD call is received.  It must accept as arguments the input arguments of METHOD.  HANDLER should return a list, whose elements are to be used as arguments for the reply message of METHOD.  This list can be composed like the input parameters in Type Conversion.

     If HANDLER wants to return just one Lisp object and it is not a cons cell, HANDLER can return this object directly, instead of returning a list containing the object.

     If HANDLER returns a reply message with an empty argument list, HANDLER must return the keyword :ignore in order to distinguish it from nil (the boolean false).

     If HANDLER detects an error, it shall return the list (:error ERROR-NAME ERROR-MESSAGE). ERROR-NAME is a namespaced string which characterizes the error type, and ERROR-MESSAGE is a free text string.  Alternatively, any Emacs signal dbus-error in HANDLER raises a D-Bus error message with the error name org.freedesktop.DBus.Error.Failed.

     When DONT-REGISTER-SERVICE is non-nil, the known name SERVICE is not registered.  This means that other D-Bus clients have no way of noticing the newly registered method.  When interfaces are constructed incrementally by adding single methods or properties at a time, DONT-REGISTER-SERVICE can be used to prevent other clients from discovering the still incomplete interface.

     The default D-Bus timeout when waiting for a message reply is 25 seconds.  This value could be even smaller, depending on the calling client.  Therefore, HANDLER should not last longer than absolutely necessary.

     dbus-register-method returns a Lisp object, which can be used as argument in dbus-unregister-object for removing the registration for METHOD.  Example:

          (defun my-dbus-method-handler (filename)
            (if (find-file filename)
                '(:boolean t)
              '(:boolean nil)))

          (dbus-register-method
           :session "org.freedesktop.TextEditor" "/org/freedesktop/TextEditor"
           "org.freedesktop.TextEditor" "OpenFile"
           #'my-dbus-method-handler)

          => ((:method :session "org.freedesktop.TextEditor" "OpenFile")
              ("org.freedesktop.TextEditor" "/org/freedesktop/TextEditor"
               my-dbus-method-handler))

     If you invoke the method org.freedesktop.TextEditor.OpenFile from another D-Bus application with a file name as parameter, the file is opened in Emacs, and the method returns either TRUE or FALSE, indicating the success of the method.  As a test tool one could use the command line tool dbus-send in a shell:

          # dbus-send --session --print-reply \
              --dest="org.freedesktop.TextEditor" \
              "/org/freedesktop/TextEditor" \
              "org.freedesktop.TextEditor.OpenFile" string:"/etc/hosts"

          -| method return sender=:1.22 -> dest=:1.23 reply_serial=2
                boolean true

     You can indicate an error by returning an :error list reply, or by raising the Emacs signal dbus-error.  The handler above could be changed like this:

          (defun my-dbus-method-handler (&rest args)
            (if (not (and (= (length args) 1) (stringp (car args))))
                (list :error
                      "org.freedesktop.TextEditor.Error.InvalidArgs"
                      (format "Wrong argument list: %S" args))
              (condition-case err
                  (find-file (car args))
                (error (signal 'dbus-error (cdr err))))
              t))

     The test then runs

          # dbus-send --session --print-reply \
              --dest="org.freedesktop.TextEditor" \
              "/org/freedesktop/TextEditor" \
              "org.freedesktop.TextEditor.OpenFile" \
              string:"/etc/hosts" string:"/etc/passwd"

          -| Error org.freedesktop.TextEditor.Error.InvalidArgs:
             Wrong argument list: ("/etc/hosts" "/etc/passwd")

          # dbus-send --session --print-reply \
              --dest="org.freedesktop.TextEditor" \
              "/org/freedesktop/TextEditor" \
              "org.freedesktop.TextEditor.OpenFile" \
              string:"/etc/crypttab"

          -| Error org.freedesktop.DBus.Error.Failed:
             D-Bus error: "File is not readable", "/etc/crypttab"

 -- Function: dbus-register-property bus service path interface property access [type] value &optional emits-signal dont-register-service
     With this function, an application declares a PROPERTY on the D-Bus BUS.

     BUS is either the keyword :system or the keyword :session.

     SERVICE is the D-Bus service name of the D-Bus.  It must be a known name.

     PATH is the D-Bus object path SERVICE is registered (see discussion of DONT-REGISTER-SERVICE below).

     INTERFACE is the name of the interface used at PATH, PROPERTY is the name of the property of INTERFACE.

     ACCESS indicates, whether the property can be changed by other services via D-Bus.  It must be either the keyword :read, :write or :readwrite.

     VALUE is the initial value of the property, it can be of any valid type (see dbus-call-method, for details).  VALUE can be preceded by a TYPE keyword.

     If PROPERTY already exists on PATH, it will be overwritten.  For properties with access type :read this is the only way to change their values.  Properties with access type :write or :readwrite can be changed by dbus-set-property.

     The interface org.freedesktop.DBus.Properties is added to PATH, including a default handler for the Get, GetAll and Set methods of this interface.  When EMITS-SIGNAL is non-nil, the signal PropertiesChanged is sent when the property is changed by dbus-set-property.

     When DONT-REGISTER-SERVICE is non-nil, the known name SERVICE is not registered.  This means that other D-Bus clients have no way of noticing the newly registered method.  When interfaces are constructed incrementally by adding single methods or properties at a time, DONT-REGISTER-SERVICE can be used to prevent other clients from discovering the still incomplete interface.

     dbus-register-property returns a Lisp object, which can be used as argument in dbus-unregister-object for removing the registration for PROPERTY.  Example:

          (dbus-register-property
           :session "org.freedesktop.TextEditor" "/org/freedesktop/TextEditor"
           "org.freedesktop.TextEditor" "name" :read "GNU Emacs")

          => ((:property :session "org.freedesktop.TextEditor" "name")
              ("org.freedesktop.TextEditor" "/org/freedesktop/TextEditor"))

          (dbus-register-property
           :session "org.freedesktop.TextEditor" "/org/freedesktop/TextEditor"
           "org.freedesktop.TextEditor" "version" :readwrite emacs-version t)

          => ((:property :session "org.freedesktop.TextEditor" "version")
              ("org.freedesktop.TextEditor" "/org/freedesktop/TextEditor"))

     Other D-Bus applications can read the property via the default methods org.freedesktop.DBus.Properties.Get and org.freedesktop.DBus.Properties.GetAll.  Testing is also possible via the command line tool dbus-send in a shell:

          # dbus-send --session --print-reply \
              --dest="org.freedesktop.TextEditor" \
              "/org/freedesktop/TextEditor" \
              "org.freedesktop.DBus.Properties.GetAll" \
              string:"org.freedesktop.TextEditor"

          -| method return sender=:1.22 -> dest=:1.23 reply_serial=3
                array [
                   dict entry(
                      string "name"
                      variant             string "GNU Emacs"
                   )
                   dict entry(
                      string "version"
                      variant             string "23.1.50.5"
                   )
                ]

     It is also possible to apply the dbus-get-property, dbus-get-all-properties and dbus-set-property functions (see Properties and Annotations).

          (dbus-set-property
           :session "org.freedesktop.TextEditor" "/org/freedesktop/TextEditor"
           "org.freedesktop.TextEditor" "version" "23.1.50")

          => "23.1.50"

          (dbus-get-property
           :session "org.freedesktop.TextEditor" "/org/freedesktop/TextEditor"
           "org.freedesktop.TextEditor" "version")

          => "23.1.50"

 -- Function: dbus-unregister-object object
     This function unregisters OBJECT from the D-Bus.  OBJECT must be the result of a preceding dbus-register-method, dbus-register-property, dbus-register-signal (see Signals) or dbus-register-monitor call.  It returns t if OBJECT has been unregistered, nil otherwise.

     When OBJECT identifies the last method or property, which is registered for the respective service, Emacs releases its association to the service from D-Bus.

Sending and receiving signals.
******************************

Signals are one way messages.  They carry input parameters, which are received by all objects which have registered for such a signal.

 -- Function: dbus-send-signal bus service path interface signal &rest args
     This function is similar to dbus-call-method.  The difference is, that there are no returning output parameters.

     The function emits SIGNAL on the D-Bus BUS.  BUS is either the keyword :system or the keyword :session.  It doesn't matter whether another object has registered for SIGNAL.

     Signals can be unicast or broadcast messages.  For broadcast messages, SERVICE must be nil.  Otherwise, SERVICE is the D-Bus service name the signal is sent to as a unicast message. (For backward compatibility, a broadcast message is also emitted if SERVICE is the known or unique name Emacs is registered at D-Bus BUS.)  PATH is the D-Bus object path SIGNAL is sent from.  INTERFACE is an interface available at PATH.  It must provide SIGNAL.

     The remaining arguments ARGS are passed to SIGNAL as arguments.  They are converted into D-Bus types as described in Type Conversion.  Example:

          (dbus-send-signal
           :session nil dbus-path-emacs
           (concat dbus-interface-emacs ".FileManager") "FileModified"
           "/home/albinus/.emacs")

 -- Function: dbus-register-signal bus service path interface signal handler &rest args
     With this function, an application registers for a signal on the D-Bus BUS.

     BUS is either the keyword :system or the keyword :session.

     SERVICE is the D-Bus service name used by the sending D-Bus object.  It can be either a known name or the unique name of the D-Bus object sending the signal.  A known name will be mapped onto the unique name of the object, owning SERVICE at registration time. When the corresponding D-Bus object disappears, signals will no longer be received.

     PATH is the corresponding D-Bus object path that SERVICE is registered at.  INTERFACE is an interface offered by SERVICE.  It must provide SIGNAL.

     SERVICE, PATH, INTERFACE and SIGNAL can be nil.  This is interpreted as a wildcard for the respective argument.

     HANDLER is a Lisp function to be called when the SIGNAL is received.  It must accept as arguments the output parameters SIGNAL is sending.

     The remaining arguments ARGS can be keywords or keyword string pairs. (For backward compatibility, the arguments ARGS can also be just strings.  They stand for the respective arguments of SIGNAL in their order, and are used for filtering as well.  A nil argument might be used to preserve the order.)  Their meaning is as follows:

     :argN STRING

     :pathN STRING
          This stands for the Nth argument of the signal. :pathN arguments can be used for object path wildcard matches as specified by D-Bus, while an :argN argument requires an exact match.

     :arg-namespace STRING
          Register for those signals, whose first argument names a service or interface within the namespace STRING.

     :path-namespace STRING
          Register for the object path namespace STRING.  All signals sent from an object path, which has STRING as the preceding string, are matched.  This requires PATH to be nil.

     :eavesdrop
          Register for unicast signals which are not directed to the D-Bus object Emacs is registered at D-Bus BUS, if the security policy of BUS allows this.  Otherwise, this argument is ignored.

     dbus-register-signal returns a Lisp object, which can be used as argument in dbus-unregister-object for removing the registration for SIGNAL.  Example:

          (defun my-dbus-signal-handler (device)
            (message "Device %s added" device))

          (dbus-register-signal
           :system "org.freedesktop.Hal" "/org/freedesktop/Hal/Manager"
           "org.freedesktop.Hal.Manager" "DeviceAdded"
           #'my-dbus-signal-handler)

          => ((:signal :system "org.freedesktop.Hal.Manager" "DeviceAdded")
              ("org.freedesktop.Hal" "/org/freedesktop/Hal/Manager"
               my-signal-handler))

     As we know from the introspection data of interface org.freedesktop.Hal.Manager, the signal DeviceAdded provides one single parameter, which is mapped into a Lisp string. The callback function my-dbus-signal-handler must therefore define a single string argument.  Plugging a USB device into your machine, when registered for signal DeviceAdded, will show you which objects the GNU/Linux hal daemon adds.

     Some of the match rules have been added to a later version of D-Bus. In order to test the availability of such features, you could register for a dummy signal, and check the result:

          (dbus-ignore-errors
            (dbus-register-signal
             :system nil nil nil nil #'ignore :path-namespace "/invalid/path"))

          => nil

Alternative buses and environments.
***********************************

Until now, we have spoken about the system and the session buses, which are the default buses to be connected to.  However, it is possible to connect to any bus with a known address.  This is a UNIX domain or TCP/IP socket.  Everywhere, where a BUS is mentioned as argument of a function (the keyword :system or the keyword :session), this address can be used instead.  The connection to this bus must be initialized first.

 -- Function: dbus-init-bus bus &optional private
     This function establishes the connection to D-Bus BUS.

     BUS can be either the keyword :system or the keyword :session, or it can be a string denoting the address of the corresponding bus.  For the system and session buses, this function is called when loading dbus.el, there is no need to call it again.

     If Emacs was invoked when there was no D-Bus session bus available yet, you can set the environment variable DBUS_SESSION_BUS_ADDRESS once the session bus daemon is running and offering the address.  Calling dbus-init-bus initializes the connection to the session bus.

          (setenv "DBUS_SESSION_BUS_ADDRESS" "unix:path=/run/user/1000/bus")

          => "unix:path=/run/user/1000/bus"

          (dbus-init-bus :session)

          => 2

     dbus-init-bus returns the number of connections this Emacs session has established to the BUS under the same unique name (see dbus-get-unique-name).  It depends on the libraries Emacs is linked with, and on the environment Emacs is running.  For example, if Emacs is linked with the GTK+ toolkit, and it runs in a GTK+-aware environment like GNOME, another connection might already be established.

     When PRIVATE is non-nil, a new connection is established instead of reusing an existing one.  It results in a new unique name at the BUS.  This can be used, if it is necessary to distinguish from another connection used in the same Emacs process, like the one established by GTK+.  If BUS is the keyword :system or the keyword :session, the new private connection is identified by the keywords :system-private or :session-private, respectively.

     Example: You initialize a connection to the AT-SPI bus on your host:

          (setq my-bus
                (dbus-call-method
                 :session "org.a11y.Bus" "/org/a11y/bus"
                 "org.a11y.Bus" "GetAddress"))

          => "unix:abstract=/tmp/dbus-2yzWHOCdSD,guid=a490dd26625870ca1298b6e10000fd7f"

          ;; If Emacs is built with GTK+ support, and you run in a GTK+-enabled
          ;; environment (like a GNOME session), the initialization reuses the
          ;; connection established by GTK+'s atk bindings.
          (dbus-init-bus my-bus)

          => 2

          (dbus-get-unique-name my-bus)

          => ":1.19"

          ;; Open a new connection to the same bus.  This supersedes the
          ;; previous one.
          (dbus-init-bus my-bus 'private)

          => 1

          (dbus-get-unique-name my-bus)

          => ":1.20"

     D-Bus addresses can specify a different transport.  A possible address could be based on TCP/IP sockets, see next example.  Which transport is supported depends on the bus daemon configuration, however.

 -- Function: dbus-setenv bus variable value
     This function sets the value of the BUS environment VARIABLE to VALUE.

     BUS is either a Lisp keyword, :system or :session, or a string denoting the bus address.  Both VARIABLE and VALUE should be strings.

     Normally, services inherit the environment of the bus daemon.  This function adds to or modifies that environment when activating services.

     Some bus instances, such as :system, may disable setting the environment.  In such cases, or if this feature is not available in older D-Bus versions, this function signals a dbus-error.

     As an example, it might be desirable to start X11 enabled services on a remote host's bus on the same X11 server the local Emacs is running.  This could be achieved by

          (setq my-bus "unix:host=example.gnu.org,port=4711")

          => "unix:host=example.gnu.org,port=4711"

          (dbus-init-bus my-bus)

          => 1

          (dbus-setenv my-bus "DISPLAY" (getenv "DISPLAY"))

          => nil

Errors and events.
******************

The internal actions can be traced by running in a debug mode.

 -- Variable: dbus-debug
     If this variable is non-nil, D-Bus specific debug messages are raised.

Input parameters of dbus-call-method, dbus-call-method-asynchronously, dbus-send-signal, dbus-register-method, dbus-register-property and dbus-register-signal are checked for correct D-Bus types.  If there is a type mismatch, the Lisp error wrong-type-argument D-Bus ARG is raised.

All errors raised by D-Bus are signaled with the error symbol dbus-error.  If possible, error messages from D-Bus are appended to the dbus-error.

 -- Special Form: dbus-ignore-errors forms...
     This executes FORMS exactly like a progn, except that dbus-error errors are ignored during the FORMS (the macro returns nil then).  These errors can be made visible when dbus-debug is set to non-nil.

Incoming D-Bus messages are handled as Emacs events, see Misc Events (elisp).  They are retrieved only, when Emacs runs in interactive mode.  The generated event has this form:

     (dbus-event BUS TYPE SERIAL SERVICE DESTINATION PATH INTERFACE MEMBER
                 HANDLER &rest ARGS)

BUS identifies the D-Bus the message is coming from.  It is either a Lisp keyword, :system, :session, :system-private or :session-private, or a string denoting the bus address.

TYPE is the D-Bus message type which has caused the event.  It can be dbus-message-type-invalid, dbus-message-type-method-call, dbus-message-type-method-return, dbus-message-type-error, or dbus-message-type-signal. SERIAL is the serial number of the received D-Bus message, unless TYPE is equal dbus-message-type-error.

SERVICE and PATH are the unique name and the object path of the D-Bus object emitting the message.  DESTINATION is the D-Bus name the message is dedicated to, or nil in case the message is a broadcast signal.

INTERFACE and MEMBER denote the message which has been sent.  When TYPE is dbus-message-type-error, MEMBER is the error name.

HANDLER is the callback function which has been registered for this message (see Signals).  ARGS are the typed arguments as returned from the message.  They are passed to HANDLER without type information, when it is called during event handling in dbus-handle-event.

In order to inspect the dbus-event data, you could extend the definition of the callback function in Signals:

     (defun my-dbus-signal-handler (&rest args)
       (message "my-dbus-signal-handler: %S" last-input-event))

There exist convenience functions which could be called inside a callback function in order to retrieve the information from the event.

 -- Function: dbus-event-bus-name event
     This function returns the bus name EVENT is coming from.  The result is either the keyword :system or the keyword :session.

 -- Function: dbus-event-message-type event
     This function returns the message type of the corresponding D-Bus message.  The result is a natural number.

 -- Function: dbus-event-serial-number event
     This function returns the serial number of the corresponding D-Bus message.  The result is a natural number.

 -- Function: dbus-event-service-name event
     This function returns the unique name of the D-Bus object EVENT is coming from.

 -- Function: dbus-event-destination-name event
     This function returns the unique name of the D-Bus object EVENT is dedicated to.

 -- Function: dbus-event-path-name event
     This function returns the object path of the D-Bus object EVENT is coming from.

 -- Function: dbus-event-interface-name event
     This function returns the interface name of the D-Bus object EVENT is coming from.

 -- Function: dbus-event-member-name event
     This function returns the member name of the D-Bus object EVENT is coming from.  It is either a signal name or a method name.

 -- Function: dbus-event-handler event
     This function returns the handler the D-Bus object EVENT is applied with.

 -- Function: dbus-event-arguments event
     This function returns the arguments the D-Bus object EVENT is carrying on.

D-Bus errors are not propagated during event handling, because it is usually not desired.  D-Bus errors in events can be made visible by setting the variable dbus-debug to non-nil.  They can also be handled by a hook function.

 -- Variable: dbus-event-error-functions
     This hook variable keeps a list of functions, which are called when a D-Bus error happens in the event handler.  Every function must accept two arguments, the event and the error variable caught in condition-case by dbus-error.

     Such functions can be used to adapt the error signal to be raised. Example:

          (defun my-dbus-event-error-handler (event error)
            (when (string-equal (concat dbus-interface-emacs ".FileManager")
                                (dbus-event-interface-name event))
              (message "my-dbus-event-error-handler: %S %S" event error)
              (signal 'file-error (cdr error))))

          (add-hook 'dbus-event-error-functions #'my-dbus-event-error-handler)

Hook functions should take into account that there might be other D-Bus applications running.  They should therefore check carefully, whether a given D-Bus error is related to them.

Monitoring messages.
********************

 -- Function: dbus-register-monitor bus &optional handler &key type sender destination path interface member
     This function registers HANDLER for monitoring messages on the D-Bus BUS.

     BUS is either a Lisp keyword, :system or :session, or a string denoting the bus address.

     HANDLER is the function to be called when a D-Bus event to be monitored arrives.  It is called with the ARGS slot of the D-Bus event (see Errors and Events), which are stripped off the type keywords.  If HANDLER is nil, the default handler dbus-monitor-handler is applied.  This default handler behaves similar to the dbus-monitor program.

     The other arguments are keyword-value pairs.  :type TYPE defines the message type to be monitored.  If given, it must be equal one of the strings method_call, method_return, error or signal.

     :sender SENDER and :destination DESTINATION are D-Bus names.  They can be unique names, or well-known service names.

     :path PATH is the D-Bus object to be monitored. :interface INTERFACE is the name of an interface, and :member MEMBER is either a method name, a signal name, or an error name.

     dbus-register-monitor returns a Lisp object, which can be used as argument in dbus-unregister-object for removing the monitor.

     The following form shows all D-Bus events on the session bus in buffer *D-Bus Monitor*:

          (dbus-register-monitor :session)

     And this form restricts the monitoring on D-Bus errors:

          (dbus-register-monitor :session nil :type "error")

 -- Command: dbus-monitor &optional bus
     This command invokes dbus-register-monitor interactively, and switches to the monitor buffer.

GNU Free Documentation License
******************************

     [file doclicense.texi not included]